ぬえさぶろうのAnimate放送部

2025/02/25

作業内容

今後の改善点

• 画像ファイルを表示してみよう
• イベントをつかってみよう
• 画像を動かしてみよう
• 複数の画像をスマートに読み込む
• キーボードやマウスの入力をチェックする
• 弾と敵の当たり判定
• ゲームスコアと難易度調整の処理
• 効果音を鳴らそう

2025/02/19

作業内容

今後の改善点

//サウンドが鳴っている間はアニメーションする
package{
	import flash.display.Sprite;
	import flash.filters.BlurFilter;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.media.Sound;
	import flash.media.SoundChannel;
	
	public class PlayBass extends Sprite{
		var sp1:Sprite;
		var sp2:Sprite;
		var lineSp:Sprite;
		var dr:uint;
		var ratio:Number; //減衰率
		var degree:Number;
		var mySnd:Sound;
		//コンストラクタ
		public function PlayBass(){
			//サウンドシンボルから再生するサウンドを作る
			mySnd = new chime();
			//弦を結ぶスプライト
			sp1 = new Sprite();
			sp2 = new Sprite();
			sp2.x = sp1.x = 200;
			sp2.y = sp1.y + 250;
			sp1.graphics.beginFill(0x666666);
			sp1.graphics.drawCircle(0, 0, 2);
			sp1.graphics.endFill();
			sp2.graphics.beginFill(0x666666);
			sp2.graphics.drawCircle(0, 0, 2);
			sp2.graphics.endFill();
			addChild(sp1);
			addChild(sp2);
			//弦を描くスプライト
			lineSp = new Sprite();
			lineSp.buttonMode = true;
			lineSp.addEventListener(MouseEvent.MOUSE_DOWN,pickLine);
			addChild(lineSp);
			//弦を描く
			drawLine();
		}//public function PlayBass()
		//弦をマウスダウンで再生開始
		private function pickLine(event:MouseEvent):void{
			//サウンド再生
			var sndChannel:SoundChannel = mySnd.play();
			//再生完了イベントにリスナー登録
			sndChannel.addEventListener(Event.SOUND_COMPLETE, sndComplete);
			//弦の揺れ幅
			dr = 20;
			degree = 0;
			ratio = 1.0;
			var blur:BlurFilter = new BlurFilter();
			blur.blurX = 2;
			blur.blurY = 0;
			//揺れるアニメーションスタート
			lineSp.filters=[blur];
			lineSp.addEventListener(Event.ENTER_FRAME,swingLine);
		}//private function pickLine
		private function swingLine(event:Event):void{
			//曲線のコントロールポイントを揺らす角度を進める
			degree = degree+90%360; 
			//揺れ幅の減衰
			dr *= ratio;
			/*弦を再描画する*/
			drawLine();
			/*揺れ幅が１以下のとき揺れを止める*/
			if(dr < 1){
				//フィルタ解除
				lineSp.filters = [];
				lineSp.removeEventListener(Event.ENTER_FRAME, swingLine);
			}
		}/*function swingLine*/
		//s1からs2の間に曲線の弦を描く
		private function drawLine():void{
			//コントロールポイントを揺らす
			var ctx:Number = dr*Math.sin(degree*Math.PI/180);
			var cty:Number = sp2.y/2;
			//曲線を描きなおす
			lineSp.graphics.clear();
			lineSp.graphics.lineStyle(3,0x666666);
			lineSp.graphics.moveTo(sp1.x,sp1.y);
			lineSp.graphics.curveTo(ctx,cty,sp2.x,sp2.y);
		}/*function drawLine()*/
		//サウンド再生完了処理
		private function sndComplete(event:Event):void{
			//弦の振幅を減少させる
			ratio = 0.5;
		}
	}//class PlayBass
}//package

変数名	用途
sp1	始点
sp2	終点
lineSp	弦
dr	揺れ幅
ratio	減衰率
degree	角度
mySnd	サウンド

変数名	用途
beginFill(0xFF0000)	赤で塗る
moveTo(x,y):void	ラインの始点位置を設定する
lineTo(x,y):void	直線の終点位置を設定する
endFill()	描画を終了する
BlurFilter(blurX,blurY,quality)	表示オブジェクトにぼかし効果を与えるフィルタクラス
curveTo(controlX:Number,controlY:Number, anchorX:Number,anchorY:Number):void	現在の描画位置から指定したアンカーポイントのｘｙ座標まで、コントロールポイントを指定のxy座標に設定したい曲線を描く

2025/02/01

作業内容

Adobe Auditionを使って音声ファイルをmp3に変換する

	Adobe Auditionで音声データを読み込む
	音声データを書き出す
	形式をMP3オーディオ(.mp3)を選択 サンプルタイプを44100HZ　に変更 マーカーと他のメタデータを含めるのチェックをはずす